/*
 * Copyright 2020 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

package org.gradle.internal.execution.steps

import com.google.common.collect.ImmutableSet
import com.google.common.collect.ImmutableSortedMap
import org.gradle.internal.execution.ImplementationVisitor
import org.gradle.internal.execution.InputFingerprinter
import org.gradle.internal.execution.UnitOfWork
import org.gradle.internal.execution.impl.DefaultInputFingerprinter
import org.gradle.internal.fingerprint.CurrentFileCollectionFingerprint
import org.gradle.internal.hash.ClassLoaderHierarchyHasher
import org.gradle.internal.hash.TestHashCodes
import org.gradle.internal.snapshot.ValueSnapshot
import org.gradle.internal.snapshot.impl.ImplementationSnapshot

class IdentifyStepTest extends StepSpec<ExecutionRequestContext> {
    def delegateResult = Mock(Result)
    def inputFingerprinter = Mock(InputFingerprinter)
    def classloaderHierarchyHasher = Stub(ClassLoaderHierarchyHasher) {
        getClassLoaderHash(_ as ClassLoader) >> TestHashCodes.hashCodeFrom(1234)
    }

    interface MyWorkClass extends UnitOfWork {
    }

    def step = new IdentifyStep<>(buildOperationRunner, classloaderHierarchyHasher, delegate)

    def "delegates with assigned identity"() {
        def inputSnapshot = Mock(ValueSnapshot)
        def inputFilesFingerprint = Mock(CurrentFileCollectionFingerprint)
        def implementationType = MyWorkClass
        def implementationSnapshot = ImplementationSnapshot.of(implementationType.name, TestHashCodes.hashCodeFrom(1234))
        def additionalImplementations = [
            ImplementationSnapshot.of("FirstAction", TestHashCodes.hashCodeFrom(2345)),
            ImplementationSnapshot.of("SecondAction", TestHashCodes.hashCodeFrom(3456))
        ]

        when:
        def result = step.execute(work, context)

        then:
        result == delegateResult
        _ * work.visitImplementations(_) >> { ImplementationVisitor visitor ->
            visitor.visitImplementation(implementationType)
            additionalImplementations.each {
                visitor.visitAdditionalImplementation(it)
            }
        }

        _ * work.getInputFingerprinter() >> inputFingerprinter

        1 * inputFingerprinter.fingerprintInputProperties(
            ImmutableSortedMap.of(),
            ImmutableSortedMap.of(),
            ImmutableSortedMap.of(),
            ImmutableSortedMap.of(),
            _,
            _
        ) >> new DefaultInputFingerprinter.InputFingerprints(
            ImmutableSortedMap.of(),
            ImmutableSortedMap.of("input", inputSnapshot),
            ImmutableSortedMap.of(),
            ImmutableSortedMap.of("input-files", inputFilesFingerprint),
            ImmutableSet.of()
        )

        1 * delegate.execute(work, _ as IdentityContext) >> { UnitOfWork work, IdentityContext delegateContext ->
            assert delegateContext.inputProperties as Map == ["input": inputSnapshot]
            assert delegateContext.inputFileProperties as Map == ["input-files": inputFilesFingerprint]
            assert delegateContext.implementation == implementationSnapshot
            assert delegateContext.additionalImplementations as List == additionalImplementations
            delegateResult
        }
    }
}
